Skip blank pages in PDF

[bprice]

Hi Everyone,
I'm wondering if someone can help me out here.

I have my own script that I've made for exporting PDF's... works great.

Now... I have a need to have pages in a Corel drawing that doesn't print, or show in the PDF output... for which I turn off the print setting in the object manager for the appropriate layers. Again... this is all fine.

Where I run into the problem is that if I have two pages, and the second page has the items I don't want to appear in the PDF... the page still exists in the PDF... just with nothing in it.

Technically the page does have things on it, they just don't appear on a printable layer. Is there a way to make the PDF ignore a page without any "printable" data on it?

Any suggestions would be appreciated.

Thanks!

[shelbym]

Here is what I came up with, basically you look at each of the layers on a page and if the page has no printable layer your exclude it.

Sub CreatePDFwithPrintablePages()
    With ActiveDocument.PDFSettings
        .PublishRange = 3 'Prints a PageRange
        .PageRange = GetPrintablePages 'Printable pages returned from function
    End With

    ActiveDocument.PublishToPDF "D:\Temp\MyPDF.pdf"
End Sub

Private Function GetPrintablePages() As String
    Dim p As Page
    Dim strPrintablePages
    
    For Each p In ActiveDocument.Pages
        If SearchForPrintablePages(p) Then strPrintablePages = strPrintablePages & p.Index & ","
    Next p
    
    GetPrintablePages = Left(strPrintablePages, Len(strPrintablePages) - 1) 'Trim off the last comma
End Function

Private Function SearchForPrintablePages(ByVal p As Page) As Boolean
    Dim l As Layer
    
    For Each l In p.Layers
        If l.Printable Then
            SearchForPrintablePages = True
            Exit Function
        End If
    Next l
    
    SearchForPrintablePages = False
End Function

It should work, a few ideas for improvement would be to convert the string "1,2,3,6" to "1-3,6" also you could have a printable layer with no shapes on it, and currently it would print that page thus giving you a blank page, so you might want to add a check for this.

Hopefully it gets you started and shows it is possible,

-Shelby

[bprice]

Much appreciated Sir! I'll try it out!