X4 SaveAs Causing Crash

My company is upgrading from CorelDraw11 to X4. I have a macro to save files to a certain folder and I want a yes/no option to overwrite existing files.

I am very new to VBA. I learned it on my own a month ago to speed up our work in CorelDraw 11, so my code is probably abstract, but it did what I wanted it to do in version 11 just fine, however it causes X4 to crash.

Any help is greatly appreciated.

Sub Ctrl_F9()

On Error GoTo ErrorHandler:
Dim Response2 As Integer

Response = InputBox("Enter File Name to Save to EngravingCDR")
If Response = "" Then Exit Sub
Dim opt As New StructSaveAsOptions
    opt.Filter = cdrCDR
    opt.Overwrite = False
    opt.Range = cdrAllPages
    ActiveDocument.SaveAs "O:\Oentry\Engravingcdr\" & Response & ".cdr", opt
     
ErrorHandler:
     If Err.Number = -2147467259 Then
     Response2 = MsgBox("Overwrite Existing File?", vbYesNo)
     If Response2 = vbYes Then
     Dim Opt2 As New StructSaveAsOptions
    Opt2.Filter = cdrCDR
    Opt2.Overwrite = True
    Opt2.Range = cdrAllPages
    ActiveDocument.SaveAs "O:\Oentry\Engravingcdr\" & Response & ".cdr", Opt2
    Else
    Exit Sub
    End If
 End If
 Exit Sub
End Sub

[shelbym]

It is better to test if the file exists then to try and rely on an error catch. Try this....it should work for you on X4

Sub Ctrl_F9()
    Dim Response As String
    Dim Response2 As VbMsgBoxResult
    Dim opt As New StructSaveAsOptions

    Response = InputBox("Enter File Name to Save to EngravingCDR", "SaveAs")
    If Response = "" Then Exit Sub
    
    If Dir("O:\Oentry\Engravingcdr\" & Response & ".cdr") <> "" Then 'Test to see if the file exists
        Response2 = MsgBox("Overwrite Existing File?", vbYesNo, "SaveAs")
        If Response2 = vbNo Then Exit Sub
    End If
    
    opt.Filter = cdrCDR
    opt.Overwrite = True
    opt.Range = cdrAllPages
    ActiveDocument.SaveAs "O:\Oentry\Engravingcdr\" & Response & ".cdr", opt
End Sub

Best of luck,

-Shelby

That works perfectly! Thanks a ton Shelby, you've saved me a lot of headaches!