Please someone check this!

[knowbodynow]

Hello, I'd be grateful if someone with CorelDraw 12 would try this experiment. Create a new document and rename Layer 1 as "picture layer". Create a new layer and name it "word layer". Then try and run the following sub.

Sub Layercheck()

ActiveDocument.ActivePage.Layers("word layer").Name = "text"
ActiveDocument.ActivePage.Layers("picture layer").Name = "images"

End Sub

I get an out of range error. The picture layer is being changed to text. What am I doing wrong? Is this some kind of bug or corruption or am I being crazy?

Thanks,

Chris (hunt)

[shelbym]

Try it this way:

Sub Layercheck()

ActivePage.Layers("word layer").Activate
ActiveLayer.Name = "text"

ActivePage.Layers("picture layer").Activate
ActiveLayer.Name = "images"

End Sub

Good luck,

Shelby

[knowbodynow]

Thanks Shelby, that worked. The code I was trying to use is straight from page 47 of the Programming Guide for VBA

Do you know anything about checking for the existence of layers? I tried using Alex's macro from this thread but I have a problem with master layers. The thread was created in 2002 so I'm hoping there is another way now.

Best wishes,

Chris

[shelbym]

What is the problem you are running into. Alex's example is the way I would do it. I use something very similar for objectdata fields, to check and make sure they exist.

Shelby

[knowbodynow]

Here's an example. If I run the macro more than once I get an error message. If it is a master layer it keeps trying to create the back layer. If back isn't a master layer there is no error. I guess I'm doing something wrong with the master layer? I tried using If lr not is nothing then as well but had the same problem

Chris

Sub Layercheck()
Dim lr0 As Layer

Set lr = FindLayer(ActivePage, "back")
If lr Is Nothing Then
ActiveDocument.ActivePage.CreateLayer ("back")
Set lr0 = ActiveDocument.ActivePage.Layers("back")
lr0.Master = True
End If
End Sub

------------------------

Public Function FindLayer(ByVal pg As Page, ByVal Name As String) As Layer
    Dim LayerFound As Layer
    Dim lr As Layer
    
    Set LayerFound = Nothing
        
    For Each lr In pg.Layers
        If lr.Name = Name Then
            Set LayerFound = lr
            Exit For
        End If
    Next lr
    
    Set FindLayer = LayerFound
    
End Function

[knowbodynow]

Can anyone please confirm if the code posted in my previous post should work with master layers? It seems my check is ignored if the layer is a master layer and I get an error because the layer is being created more than once.

Thanks,

Chris (Hunt)

hI gUYS,

i HAVE SIMILER STUFF RUNNING IN MY SYSTEM,U TRY TO DO AS FOLLOWS:

BLNlAYEREXISTS=FALSE
fOR EACH LAYER IN ACTIVE PAGE.LAYERS
IF LAYER.NAME="sOME LAYER YOU WANT" THEN
BLNlAYEREXISTS=TRUE
EXIT FOR
ELSE
GOTO NEXTLOOP
ENDIF
NEXTLOOP:
NEXT
IF NOT BLNlAYEREXISTS THEN
DO YOUR OPRATION
ENDIF

tHIS IS THE WAY I USE IN MY PROGRAM AND IT WORKS FOR ALL LAYERS.

THANKS
AMOL

[knowbodynow]

Thanks for the idea, unfortunately I'm still getting an error message with master layers. Here is what I tried:

Dim lr0 As Layer

blnlayerexists = False
For Each Layer In ActivePage.Layers
If Layer.Name = "back" Then
blnlayerexists = True
Exit For
Else
GoTo nextloop
End If
nextloop:
Next
If Not blnlayerexists Then
ActiveDocument.ActivePage.CreateLayer ("back")
Set lr0 = ActiveDocument.ActivePage.Layers("back")
lr0.Master = True

End If

If I run this more than once I get an error message. There seems to be some kind of problem with master layers.

Chris

[Alex]

Chris,

Yes, there is a problem, but not so much with CorelDRAW but with your code. Layers collection on a regular page just includes the layers of that page. It doesn't include master layers. That's why the first time you are able to create the layer "back". Then you run the code again, it can't find that layer in ActivePage.Layers collection because your layer is a master layer and is not listed in the page's layer collection. Then you try to create the layer again and CorelDRAW doesn't allow to create two layers with the same name, so the error occurs.

I had a bit of a trouble going through your code because of the text formatting, so I rewrote it a bit for others who could be interested in this conversation. I hope this version is a bit more readable (yet still exibits the problem). I also simplified it a bit. You can see that I have removed a few lines as they were not needed:

Sub EnsureLayerExists()
    Dim lr As Layer
    Dim bLayerExists As Boolean
    
    bLayerExists = False
    For Each lr In ActivePage.Layers
        If lr.Name = "back" Then
            bLayerExists = True
            Exit For
        End If
    Next lr
    
    If Not bLayerExists Then
        Set lr = ActivePage.CreateLayer("back")
        lr.Master = True
    End If
End Sub

Now, fortunately, CorelDRAW X3 has another layer collection of the Page object that lists both regular and master layers. It is called Page.AllLayers. So, simple modification of the code makes it work:

Sub EnsureLayerExists()
    Dim lr As Layer
    Dim bLayerExists As Boolean
    
    bLayerExists = False
    For Each lr In ActivePage.AllLayers
        If lr.Name = "back" Then
            bLayerExists = True
            Exit For
        End If
    Next lr
    
    If Not bLayerExists Then
        Set lr = ActivePage.CreateLayer("back")
        lr.Master = True
    End If
End Sub

If you are using a previous version of CorelDRAW, then you will need to iterate through the layers of the master page instead:

Sub EnsureLayerExists()
    Dim lr As Layer
    Dim bLayerExists As Boolean
    
    bLayerExists = False
    For Each lr In ActiveDocument.MasterPage.Layers
        If lr.Name = "back" Then
            bLayerExists = True
            Exit For
        End If
    Next lr
    
    If Not bLayerExists Then
        Set lr = ActivePage.CreateLayer("back")
        lr.Master = True
    End If
End Sub

Note that Document.MasterPage property only available in CorelDRAW 12 and X3. If you use v10 or 11 you will need to use Document.Pages(0) to access the master page.

[knowbodynow]

Thank you, thank you - I've got my script working and learnt more about scripting as well. You're brilliant!

Best wishes,

Chris