break until single character

how do I count the number of characters in shape.text

[ddonnahoe]

This should be what you are looking for...

Option Explicit

Sub CountLetters()
    Dim LetterArray(33 To 255) As Long
    Dim n As Long
    Dim s As Shape
    Dim strText As String
    Dim c As Integer
    
    For n = 33 To 255
        LetterArray(n) = 0
    Next n
    
    For Each s In ActivePage.FindShapes(Type:=cdrTextShape)
        strText = s.Text.Frame.Range.Text
        For n = 1 To Len(strText)
            c = Asc(Mid$(strText, n, 1))
            If c > 32 And c < 256 Then
                LetterArray(c) = LetterArray(c) + 1
            End If
        Next n
    Next s
    
    strText = "Letter occurence statistics:" & vbCrLf
    For n = 33 To 255
        If LetterArray(n) > 0 Then
            strText = strText & Chr$(n) & " = " & LetterArray(n) & vbCrLf
        End If
    Next n
    
    With CreateDocument
        .ActiveLayer.CreateParagraphText 0, 0, .ActivePage.SizeWidth, .ActivePage.SizeHeight, strText
    End With
End Sub

[shelbym]

Or if you want everything you can do something like this:

Sub Test()

Dim s As Shape
Dim d As Document
Dim t As Text

Set d = CreateDocument
Set s = d.ActiveLayer.CreateParagraphText(2, 2, 8, 8, "This is a test.")

Set t = s.Text
MsgBox t.Story.Characters.Count

End Sub

Best,

Shelby

Maybe the original post need the code below..
Anyway it is a usefull and parametric sub!

Public Sub BreakApartToLetters(intMainLoops as integer)
Dim cdrShape As Shape
Dim intCounter As Integer
    For intCounter = 1 To intMainLoops
        For Each cdrShape In ActiveDocument.ActivePage.Shapes
            If cdrShape.Type = cdrTextShape Then
                cdrShape.BreakApart
            End If
        Next
    Next
End Sub

The steps for each main loop are the below...
1. Paragraph to lines
2. Lines to words
3. Words to letters

So when you have paragraphs
intMainLoops = 3 ....and you will get letters
intMainLoops = 2 ....and you will get words
intMainLoops = 1 ....and you will get lines

when lines
intMainLoops = 2 ....and you will get letters
intMainLoops = 1 ....and you will get words

when words
intMainLoops = 1 ....and you will get letters

It affects on all objects in the active page.
You could do it on the selection by altering the "ActiveDocument.ActivePage.Shapes" with "Selection".