Mistake that filling object

[0meg@]

I have some code for prepress my work but there is some strange behaviour with one logo (attach file). The part of code this:


Dim srAll As ShapeRange
Dim shprgb As Shape
Dim ff As FountainFill

Set srAll = ActivePage.Shapes.All
srAll.ConvertToCurves

For Each shprgb In srAll
If shprgb.Fill.Type = cdrUniformFill Then
If shprgb.Fill.UniformColor.Type = cdrColorRGB Then
shprgb.Fill.UniformColor.ConvertToCMYK
End If
ElseIf shprgb.Fill.Type = cdrFountainFill Then
Set ff = shprgb.Fill.Fountain
For i = 0 To ff.Colors.Count + 1
ff.Colors(i).Color.ConvertToCMYK
Next i
End If
Next shprgb

make shape with RGB Fill white be RGB Fill Green (outline color). Need some help to understand where is mistake?

[Alex]

It looks like the problem is that your logo is a group but you are not looking into groups. You just go through the top level objects on the page. You need to look through children of a group to make sure you inspect individual objects.

Also you can call "Shape.CanHaveFill" to make sure you are not trying to apply a fill to an object (like a group) that can't have a fill in the first place.

You might use Shapes.FindShapes method to filter out only the objects that actually have RGB colors in them. Here is a modified macro that does all this:

Public Sub TestFill()
    Dim srAll As ShapeRange
    Dim shprgb As Shape
    Dim ff As FountainFill
    Dim ffc As FountainColor
    
    Set srAll = ActivePage.Shapes.All
    srAll.ConvertToCurves
    
    For Each shprgb In ActivePage.Shapes.FindShapes(Query:="!@colors.filter($item.type='rgb').empty")
        If shprgb.CanHaveFill Then
            If shprgb.Fill.Type = cdrUniformFill Then
                If shprgb.Fill.UniformColor.Type = cdrColorRGB Then
                    shprgb.Fill.UniformColor.ConvertToCMYK
                End If
            ElseIf shprgb.Fill.Type = cdrFountainFill Then
                Set ff = shprgb.Fill.Fountain
                For Each ffc In ff.Colors
                    ffc.Color.ConvertToCMYK
                Next ffc
            End If
        End If
    Next shprgb
End Sub

[0meg@]

Thank you very much!