Can a script "remember" the last view used?

Could a script be written to remember the last view the user had when editing a CDR file?

For example, I had zoomed in on a part of an org chart and saved the file. The next time I or someone else opened that file, I'd like the drawing-display to look the same as when I last exited that file.

Xara does this automatically and it is very useful.

It would be great if something similar were in CorelDRAW when collaborating with others over our intranet .... especially those who are neophytes using Draw.

Regards, John

[shelbym]

This should be possible. But I haven't gotten it to work yet, was wondering if someone else in the group could tell me what I am doing wrong. Here is my code:

Private Sub GlobalMacroStorage_DocumentOpen(ByVal Doc As Document, ByVal FileName As String)

If CheckLastView("LastView") = True Then Doc.Views("LastView").Activate

End Sub

Private Sub GlobalMacroStorage_DocumentBeforeSave(ByVal Doc As Document, ByVal SaveAs As Boolean, ByVal FileName As String)

If CheckLastView("LastView") = True Then Doc.Views("LastView").Delete
Doc.Views.AddActiveView "LastView"

End Sub

Private Function CheckLastView(VwName As String) As Boolean
    
Dim Vw As View

For Each Vw In ActiveDocument.Views
    If Vw.Name = VwName Then
        CheckLastView = True
        Exit For
    End If
Next Vw

Set Vw = Nothing

End Function

The code creates the view on save as it should, but when you try and open the document you get a Run-time error. Per the X3 programming guide Doc.Views("LastView").Activate should work, but all I get is the error. I have tried in CorelDRAW 12 and X3 and get the same error. Ideas anyone?

Thanks,

Shelby

[shelbym]

I have tried a couple of things, and still can't get it working. Alex any ideas what I am doing wrong? Thanks,

Shelby

[wOxxOm]

Here's correct code:

Private Sub GlobalMacroStorage_DocumentOpen(ByVal doc As Document, ByVal FileName As String)
   Dim p As Page
   If doc.Properties.Exists("LastView", 0) Then
      Set p = doc.Pages(doc.Properties("LastView", 0))
      If Not p Is Nothing Then p.Activate
      doc.ActiveWindow.ActiveView.SetViewPoint _
         doc.Properties("LastView", 1), doc.Properties("LastView", 2), _
         doc.Properties("LastView", 3)
   End If
End Sub

Private Sub GlobalMacroStorage_DocumentBeforeSave(ByVal doc As Document, ByVal SaveAs As Boolean, ByVal FileName As String)
   With ActiveWindow.ActiveView
      doc.Properties("LastView", 0) = doc.ActivePage.Index
      doc.Properties("LastView", 1) = .OriginX
      doc.Properties("LastView", 2) = .OriginY
      doc.Properties("LastView", 3) = .Zoom
   End With
End Sub

it works.

doc.Views saving doesn't work - CorelDraw bug/intended behaviour

For CorelDraw12, which doesn't have .exists property you need to use this

Private Sub GlobalMacroStorage_DocumentOpen(ByVal doc As Document, ByVal FileName As String)
   Dim p As Page
   If doc.Properties("LastView", 0) <> 0 Then
      Set p = doc.Pages(doc.Properties("LastView", 0))
      If Not p Is Nothing Then p.Activate
      doc.ActiveWindow.ActiveView.SetViewPoint _
         doc.Properties("LastView", 1), doc.Properties("LastView", 2), _
         doc.Properties("LastView", 3)
   End If
End Sub

Private Sub GlobalMacroStorage_DocumentBeforeSave(ByVal doc As Document, ByVal SaveAs As Boolean, ByVal FileName As String)
   With ActiveWindow.ActiveView
      doc.Properties("LastView", 0) = doc.ActivePage.Index
      doc.Properties("LastView", 1) = .OriginX
      doc.Properties("LastView", 2) = .OriginY
      doc.Properties("LastView", 3) = .Zoom
   End With
End Sub

[shelbym]

That is a great workaround! Wish I would have thought of it. LOL. Anyway, JCS(John) here is a GMS of the finished code. It does what you asked. Just drop it into your GMS dir and you should be good to go. I have only test this in CorelDRAW X3.

Thanks,

Shelby

Okay folks, this does not work in either v12 or v13. I don't know much about these here fancy scripty things, just try and fix it and let me know what the deal is.

Thanks.