The name of the font when you change the curves

[grzjanik]

Hello.
I work in CorelDraw 12. I have a code that when you change the text to curves as the name of the curve gives the name of the font used and its size in points. You test.

Sub KrzyweOrazNazwaFontu()
Dim s As Shape, sr As ShapeRange
Dim count As Double, strName As String
Dim OrigSelection As ShapeRange
Set OrigSelection = ActiveSelectionRange
count = 1
Set sr = ActiveSelectionRange
For Each s In sr
s.CreateSelection
If s.Type = cdrTextShape Then
strName = s.Text.FontProperties.Name & " (size: " & ActiveShape.Text.FontProperties.Size & " pt)"
s.ConvertToCurves
s.Name = strName
Else
ActiveShape.ConvertToCurves
End If
count = count + 1
Next s
End Sub

I need the help to run code on the entire document (powerclips, in groups, on all pages).

Thank you in advance and best regards.
~GrzJanik

[shelbym]

I am getting old, took me a few minutes to remember how to do this in version 12. :-) This should work.

Public Sub ConvertALLTextToCurves()
    Dim p As Page
    
    For Each p In ActiveDocument.Pages
        ConvertShapes p.Shapes
    Next p
End Sub

Private Sub ConvertShapes(ss As Shapes)
    Dim s As Shape
    
    For Each s In ss
        Select Case s.Type
            Case cdrTextShape
                ConvertShapeCurves s
            Case cdrGroupShape
                ConvertShapes s.Shapes
        End Select
        On Error Resume Next
        If Not s.PowerClip Is Nothing Then
            ConvertShapes s.PowerClip.Shapes
        End If
    Next s
End Sub

Private Sub ConvertShapeCurves(s As Shape)
    Dim strName As String
    
    strName = s.Text.FontProperties.Name & " (size: " & s.Text.FontProperties.Size & " pt)"
    s.ConvertToCurves
    s.Name = strName
End Sub

Best of luck,

-Shelby

[grzjanik]

Hi.
Shelby, very big thank you for your time and willingness.
The code is work in entire document.
Your the best.
Regards.
~GrzJanik