Paste at Node enhanced?

[PAnderson]

Awhile back Shelby gave this code for pasting an object at nodes, which is perfect if you have only one object to paste:

Sub PasteClipboardAtNodes()
    Dim s As Shape, sr As ShapeRange
    Dim sclip As Shape, n As Node

    Set sr = ActiveSelectionRange
    ActiveDocument.ReferencePoint = cdrCenter
    
    Set sclip = ActiveLayer.Paste

    For Each s In sr
        If s.Type = cdrCurveShape Then
            For Each n In s.Curve.Nodes
                sclip.Duplicate.SetPosition n.PositionX, n.PositionY
            Next n
        End If
    Next s
    
    sclip.Delete
End Sub

I would like to do something similar, only the selected objects are all different. For example, I might have a list of names, each name is a separate Artistic Text object, and I want to be able to select them all Copy and have them pasted at the nodes of the selected curve.

Ideally I would like to choose whether it pastes using the object center or its left, right, top or bottom center. Or maybe it could "respect" the relative center chosen (or object origin) prior to running the macro. Can this be done?

Patti

[Joe]

Sounds like something that I should add to this little docker I'm working on...

But back to your question - this is certainly doable. Adding the origin points and such instantly inflate the amount of work, but in general you would have to define a ShapeRange instead the single sclip shape, then define an index to set the amount of shapes. Like this:

Sub PasteClipboardAtNodes()
    Dim s As Shape, sr As ShapeRange
    Dim sclip As ShapeRange, n As Node

    Dim Index As Integer

    Set sr = ActiveSelectionRange
    ActiveDocument.ReferencePoint = cdrCenter
        
  Set sclip = ActiveLayer.PasteEx
    
    Index = 1

    For Each s In sr
        If s.Type = cdrCurveShape Then
            For Each n In s.Curve.Nodes
                sclip.Shapes(Index).Duplicate.SetPosition n.PositionX, n.PositionY
                If Index < sclip.Shapes.Count Then Index = Index + 1 Else Index = 1
            Next n
        End If
    Next s
    
    sclip.Delete
End Sub

In this example the shapes are being cyclically placed at the curve points, hope that helps.

EDIT: The PasteEx is important (I pasted a version without it), since it returns a range instead of a single shape.