X5 - select objects actually on the page

[knowbodynow]

What is the simplest way to select all objects on a page without including all those on the desktop?

dim s as Shape

For Each s In activepage.Shapes
s.AddToSelection
Next s

For some reason this selects items on the desktop. I don't understand the logic. Surely the desktop should be separate from the activepage?

[shelbym]

Alright I will give you two ways to do this. The first is simply to remove the shapes on the desktop from all the shapes. You can do this like this:

Sub SelectAllExcludeDesktop()
    Dim sr As ShapeRange
    
    Set sr = ActivePage.Shapes.All
    sr.RemoveRange ActiveDocument.MasterPage.Layers("Desktop").Shapes.All
    
    sr.CreateSelection
End Sub

As you can see we create a shape range with all the shapes, then simply remove the shapes that are on the desktop layer. Pretty simple, but can we make it even simpler. Of course we can with a little CQL. :-)

Sub SelectAllExcludeDesktopCQL()
    ActivePage.Shapes.FindShapes(Query:="!@com.layer.name = 'desktop'").CreateSelection
End Sub

At first look you might say, wait, you are saying find shapes equal to 'desktop', notice the exclamation point at the beginning of the CQL statement, this is the not operator, meaning to select all shapes that are NOT on the desktop layer. So you could actually write the statement like this and get the same results:

Sub SelectAllExcludeDesktopCQL()
    ActivePage.Shapes.FindShapes(Query:="not@com.layer.name = 'desktop'").CreateSelection
End Sub

or you could also do it this way:

Sub SelectAllExcludeDesktopCQL()
    ActivePage.Shapes.FindShapes(Query:="@com.layer.name <> 'desktop'").CreateSelection
End Sub

However, it is much more common to use the exclamation point. Hope that helps,

-Shelby

[knowbodynow]

Thanks for the alternatives, Shelby. After posting I came up with this:

For Each l In p.Layers
    For Each s In l.Shapes
    If l.Name <> "Desktop" Then s.AddToSelection
    Next s
Next l

But what is the logic of having the desktop on the active page - I feel it is idiotic, and I don't use the word lightly. Surely the page and the desktop should be separate? Can you explain why they are not? Thanks again,

Chris